五一假期过完啦，又迎来了一个新的月份，爬虫君一直陪在你身边。今天，小编就和大家说说关于foreach的五个小秘密。

当我们在stata中输入help foreach的时候，突然就跳出了这么多个foreach的用法：

之前我们大多使用foreach in的命令，为什么还有这么多foreach of呀，于是大呼傻傻分不清它们的用法。不要着急，且听小编慢慢道来foreach的秘密。我们用系统数据分别解释这几个foreach的用法，第一步当然是读取我们要用的数据sysuse auto。

foreach lname in list { ... }

foreach in是我们需要循环时最为常用的命令，这种形式下允许一般形式的列表（list），列表中的各个元素用一个或多个空格彼此分离。

例如，在系统数据中：

foreach result in price mpg trunk-length {

   sum `result'

 }

在这个例子中，循环会被执行三次，即令result依次为用空格分开的price、mpg和trunk-length，来计算其描述统计量。

foreach lname of varlist list { ... }

注意：在这里of与varlist是命令格式的一部分，list后面才是接具体的变量列表。在这种形式中，list中的变量依据标准变量缩写规则进行扩展。

例如：

foreach result of varlist price mpg trunk-length {

   sum `result'

 }

在 这个例子中，循环会执行五次，令result依次对price、mpg、trunk、weight、和length进行。注意这个例子与秘密一中例子的区 分，秘密一中仅是依据空格对变量进行循环，而这里，trunk-length表示从trunk到length的变量，对于系统数据，即包括变量 trunk、weight和length。

foreach lname of local list { ... } 

& 

foreach lname of global list { ... }

这 两种形式中，foreach lname of local list { ... }是对局部宏（local list）中的各项进行循环，foreach lname of global list { ... }是对全局宏（global list）中的各项进行循环。因为很多时候，我们事先并不知道具体的要循环的元素或是要循环的元素有很多，就将这些元素存储在宏中，所以这种形式也很常 见。在所有的循环方式中，这两种方式的执行速度是最快的。

例如：

local information "price mpg rep78 headroom trunk"

foreach A of local information {

   dis "`A'"

 }

当然，这里可以直接写为：

local information "price mpg rep78 headroom trunk"

foreach A in `information' {

   dis "`A'"

 }

得出来的是一样的结果，不信你试试~

global message "length turn displacement gear_ratio"

foreach B of global message {

   dis "`B'"

 }

同样，此处也可以写为：

global message "length turn displacement gear_ratio"

foreach B in $message {

   dis "`B'"

 }

小编提示：local是局部宏，如果在一个do文件中使用，那它只在那个do文件中有效，其好处是，在不同的do文件中，可以使用相同的宏名称，不会造成冲突。而global是全局宏，一旦定义，在别处也是存在的。

foreach lname of newlist list {...}

与上一种形式相似，of与newlist也是命令格式的一部分，list中的列表为新的变量名称。在运行中stata会执行检查新的变量名是否有效，但不会自动创建。

例如：

foreach x of newlist v1-v6 {

   gen `x' =_n

 }

在这个例子中，循环会执行6次，从结果中我们可以看到已经生成了v1-v6六个新的变量，且表示第n个观测值。

foreach lname of numlist list { ... }

同理，of与numlist也是命令格式的一部分，但list后是一个数字列表。在这种形式中，stata会按照数字的方式对列表进行解读。

例如：

foreach num of numlist 1/5 10 15(3)24 30/35 {

   dis `num'

 }

在这个例子中，对列表中所要求的数字依次进行循环，并依据要求展现出来。

这种形式的foreach命令与forvalue有着类似的作用，forvalues是对连续的数值进行循环的基本命令。语句：

forvalues lname = range {

        commands referring to `lname'

        }

但注意差别就在于“连续数值”哟。因此，在使用forvalues时，后面的列表中的数字必须是连续的，因此此处第一个连续的数字就可以如下表述：

forvalues num = 1/5 {

   dis `num'

 }

除了foreach in还有这么多好用的foreach命令，能够根据不同的需求执行循环命令，小秘密都告诉你们了，还不赶紧试着用起来~

                       文字编辑：徐苾雯

技术总编：刘贝贝

往期推文推荐：

1.中国高校财经、管理与综合类期刊灌水排行榜