全要素生产率（TFP）是产量与全要素投入量之比，作为宏观经济学的重要概念，是政府制定长期政策的重要依据。也是小伙伴们观察各个行业的一大特点。

那么问题来了，我们怎么用Stata实现对各个行业全要素生产率的批量计算呢？

在这里，小编向各位介绍三种方法。

该方法主要参考（鲁晓东，连玉君，2012）以及廖冠民老师JF期刊论文《The Brain Gain of Corporate Boards: Evidence from China》中对上市公司TFP的计算方法。 

主要采用的模型如下，指标的数据来源CSMAR。

其中，表示行业j和t年的i公司的主营业务收入的对数，表示行业j和t年的i公司的员工人数的对数，主要使用的年报中披露的上市公司在册（在职）员工人数，表示行业j和t年的i公司的总资产的对数，表示行业j和t年的i公司购买商品、接受劳务实际支付的现金的对数，行业分类采取的2015年的申银万国行业分类方法。

根据上述的模型，需要计算残差，该值就是我们需要的公司的全要素生产率（TFP）的值，关键的程序如下：

打开所需使用的指标文件：

clear

set more off

global path = "F:\Empirical analysis\数据\TFP\"

use  "$path\计算TFP所需要的指标",clear

***由于后面需要根据行业和年份计算TFP，需要知道年份的最大值，所以定义局部宏yearnum来存储年份最大值

sum year

local yearnum=r(max)

***给行业进行连续编号且获取行业编号的最大值和最小值，方便下面的循环

egen indid = group(ind)

sum indid

local indnum1=r(min)

local indnum2=r(max)

***添加变量tfp，方便全要素生产率的值保存在变量tfp

gen tfp=.

***对行业和年份进行循环

forval year = 2000(1) `yearnum' {

disp `year'

     forval indid = `indnum1'(1)`indnum2'{

     disp `indid'

***确保每个年份和每个年份至少有20个样本，避免回归时样本太少

    count if year == `year' & indid==`indid'

    if r(N)<20{

      continue

    }

***按照同行业和同年份进行回归分析

regress  lnsales lnworkernum  lnasset lncashpay  if year == `year' & indid==`indid'  

***计算残差值

predict temp if year == `year' & indid ==`indid', residual

***把计算好的残差值保存在变量tfp

replace tfp=temp if year == `year' & indid ==`indid'  

drop temp

 }

}

drop if tfp==.

save "$path\tfp",replace

  除了上述方法，我们同样可以借助于Stata强大又丰富的命令进行调用，让工作更加轻松。

参考（鲁晓东，连玉君，2012）的方法以及命令opreg介绍OP方法的实现过程，首先需要使用语句“ssc install opreg”安装opreg命令，主要的程序如下：

gen lnY_add=ln_sales

gen lnK=ln(PPE)

gen lnL=ln(num)

gen lnI=ln(capital)

xi:opreg lnY_add, exit(exit) state(age lnK) proxy(lnI) free(lnL ln_material) cvars(SOE )  vce(bootstrap, seed(1357) reps(5))

predict tfp_op

ln_material PPE

其中，状态变量为age 和lnK，代理变量为企业的投资lnI，自由变量为lnL和ln_material，控制变量为SOE，退出变量为exit。

sales是主营业务收入，PPE是固定资产，num为公司的员工人数，material是公司购买商品、接受劳务实际支付的现金，capital为资本性支出，exit为是否退出市场，这个指标上市公司数据几乎没有，老师和同学建议可以用公司股权、业务等是否发生实质转移作为指标，在操作中主要以公司简称和所处行业为基准，如果两者同时发生变化了就认为原有的公司退出了市场；age是公司的成立时间，SOE是企业性质的虚拟变量。

主要参考（鲁晓东，连玉君，2012）以及help levpet, 程序如下：

levpet lnY_add, free(lnL) proxy(ln_material) capital(lnK) i(stkcd) t(year)

predict tfp_lp,omega

需要注意的是，变量和前面的变量定义都一样，唯一不同的是要对预测出来的tfp_lp取自然对数才是真正的LP方法计算出来的TFP。

小命令有大用途，这就是今天的分享，希望对诸位读者在导出实证结果中有些许的帮助，是不是被喷薄而出的回归报告集惊呆了呢。