在之前的推文中，我们讲到用rtf系列命令结合esttab和estpost将实证结果输出到rtf文件中，Stata15出现以后，我们可以利用putdocx命令创建和编辑.docx文件，今天小编给大家介绍的是，如何将实证结果输出到同一个.docx文件中。

在推文“玩转stata15—putdocx生成.docx文件”，我们介绍了如何用putdocx命令在.docx文件中录入文本内容、插入表格；推文“玩转stata15—putdocx导入图表”介绍了如何将图表输出到.docx文件；推文“玩转Stata15—putdocx append将它们粘起来！”介绍了如何多个.docx文件拼接起来。

在这几篇推文的基础之上，今天介绍如何将实证结果输出到.docx文件中，由于用putdocx命令直接将多个回归结果输出到.docx中，需要一个较为复杂的循环，因此这里的基本思路是，首先用esttab将实证结果输出到rtf文件中，然后利用wordconvert将rtf文件转换为.docx文件，（详见推文“爬虫俱乐部又出新命令了——wordconvert转换你的word文件”）最后利用putdocx append命令将两个.docx文件拼接起来。

clear all

cap mkdir E:\Stata教程\docx\

cd E:\Stata教程\docx\

! taskkill /F /IM WINWORD.EXE /T

putdocx begin

putdocx paragraph, halign(center) // 写入一段，文本内容居中

putdocx text ("实证结果展示"), font("华文楷体",60,black) bold  //输出加粗文本"实证结果展示"，字体为华文楷体，字号为60，颜色为黑色。

putdocx paragraph, halign(center) spacing(line,0.15) //新写入一段，文本内容居中，行间距为0.15英寸。

putdocx text ("Empirical Resutls"), font("华文楷体",30,black) bold linebreak  //输出加粗文本"Empirical Resutls"，字体为华文楷体，字号为30，颜色为黑色,并换行。

putdocx text ("Prof. Chuntao Lee"), font("华文楷体",20,black) bold  linebreak //输出加粗文本"Prof. Chuntao Lee"，字体为华文体，字号为20，颜色为黑色,并换行。

putdocx text ("Email："), font("华文楷体",20,black) bold  //  输出加粗文本"Prof. Chuntao Lee"，字体为华文楷体，字号为20，颜色为黑色,不进行换行。

putdocx text ("chtl@zuel.edu.cn"), font("华文楷体",15,black) bold  underline(dash) //  输出加粗文本"chtl@zuel.edu.cn"，字体为华文楷体，字号为15，颜色为黑色,给文本内容加上虚下划线。

putdocx save mytable.docx, replace //将文本内容保存成mytable.docx文件。

执行结果如下：

这一部分前边推文基本上都介绍过，这里只介绍一下，段落中的一个选项spacing(position, #[unit])，这个选项是定义行间距的。其中，position代表位置，可以为before、after、line。before表示当前段落第一行之前的行间距；after表示当前段落最后一行之后的行间距；line则表示当前段落的行间距。#[unit]表示一个数值，其单位可以是in (inch), pt (point), cm (centimeter), 和 twip (twentieth of a point)，默认单位为in（英尺）。

sysuse auto, clear

estpost summarize price mpg rep78 foreign, detail

esttab using temp.rtf, cells("count mean(fmt(3)) p50 sd(fmt(2)) min max ") compress noobs replace

这样，描述性统计结果就保存在了temp.rtf文件中。

      将前边用esttab输出的temp.rtf文件转换为.docx文件temp.docx，程序如下：

wordconvert "temp.rtf" "temp.docx", replace encoding(gb2312)

putdocx begin

putdocx pagebreak

putdocx paragraph, halign(left)  

putdocx text ("Summary Statistics"), bold

putdocx save mytable.docx, append

   putdocx append将文档temp.docx拼接到文档mytable.docx

程序如下：

putdocx append "mytable.docx" "temp.docx",saving(mytable.docx,replace)

      putdocx append在前边的推文中已经详细的介绍过，这里不再鳌述，执行结果是把描述性统计的表格拼接到了原来保存的mytable.docx文档中。

sysuse auto, clear

reg mpg weight

est store m1

reg mpg weight length

est store m2

reg mpg weight length foreign

est store m3

esttab m1 m2 m3 using temp.rtf, replace

这样，回归结果就被保存在了temp.rtf 。

将前边用esttab输出的temp.rtf文件转换为.docx文件temp.docx，程序如下：

wordconvert "temp.rtf" "temp.docx", replace encoding(gb2312)

程序如下：

putdocx begin

putdocx pagebreak

putdocx paragraph, halign(left) 

putdocx text ("Regression Table 1"), bold 

putdocx save mytable.docx, append

程序如下：

putdocx append "mytable.docx" "temp.docx",saving(mytable.docx,replace)

执行后，回归结果的表格就拼接到了之前保存的mytable.docx文档中。

到 了这里，描述性统计结果和回归结果就被输出到了同一个.docx中，其他回归结果、相关系数、t检验等结果的输出，都是这么一个过程。首先，利用 esttab输出rtf文件，然后用wordconvert将rtf文件转化为.docx文件，最后用putdocx append将两个.docx文件拼接起来。

这仅仅是Stata15众多新功能之一，后续我们会陆续介绍更多在Stata15中好玩好用的命令，好期待呐！Stata15真是好用的不得了，亲爱的读者朋友们，你有没有心动呢？北京友万信息科技有限公司作为Stata软件在中国大陆的指定经销商及合作伙伴，希望能给Stata中国用户提供更多服务与支持，并帮助中国用户建立完善的软件售后服务体系。

★ 基础服务：

1、Stata软件购买服务；

2、Stata软件升级服务；

3、Stata软件培训服务；

★ 附加服务：

4、Stata软件定制培训计划；

5、Stata软件研讨会；

6、Stata软件中国用户大会；

★ 增值服务：

7、提供数据处理/大数据分析/统计咨询及网络爬虫服务；

8、提供软件管理平台服务，本地部署让管理更便捷；

9、提供经管类案例库，可实时导出PPT格式用于老师讲课与教学相结合；

10、针对学校和科研机构提供内训服务, 行业专家上门服务。

联系人：徐青青（18610597626；010-56451129）

以上就是今天给大家分享的内容了，说得好就赏个铜板呗！有钱的捧个钱场，有人的捧个人场~。

应广大粉丝要求，爬虫俱乐部的推文公众号打赏功能可以开发票啦，累计打赏超过1000元我们即可给您开具发票，发票类别为“咨询费”。用心做事，只为做您更贴心的小爬虫。第一批发票已经寄到各位小主的手中，大家快来给小爬虫打赏呀~