在前边的推文中，我们介绍了用putdocx命令将list结果输出到docx文件，在此基础上，今天给大家介绍一下如何将list结果加上表头，并以不同的表格格式分批输出到docx文件中，并分页展示。

首先，我们输入文本“Auto.dta，list结果展示”，并保存为mytable.docx文件。程序如下：

clear all

cap mkdir E:\Stata教程\docx\

cd E:\Stata教程\docx\

! taskkill /F /IM WINWORD.EXE /T

putdocx begin

putdocx paragraph, halign(center)

putdocx text ("Auto.dta"), font("Times New Roman",60,blue) bold linebreak

putdocx text ("list结果展示"), font("华文楷体",50,black) bold

putdocx save mytable1.docx, replace

以上程序在前边putdocx系列推文中已经介绍过，这里不再赘述，执行结果如下：

输出1/20行观测值到mytable.docx文件中，程序如下：

sysuse auto,clear

putdocx begin

putdocx pagebreak

putdocx paragraph, halign(left) spacing(after,0) 

putdocx text ("Auto,list in 1/20"), bold

putdocx table tbl = data("make price weight length") in 1/20, varnames layout(autofitwindow)  

putdocx save mytable.docx,append

首先，调用auto数据，在开始使用putdocx命令后（putdocx begin），用putdocx pagebreak进行换页，然后开始新的一段，输入文本"Auto,list in 1/20"，最后将make、price、weight、length四个变量的前20行数据输出到mytable.docx文件中。

这里，介绍一下table选项中的layout选项，autofitwindow表示根据窗口大小自动调整列宽；autofitcontents表示根据表格内容自动调整列宽；fixed表示表格所有的列都相同。默认以窗口大小自动调节列宽。

执行结果如下所示:

输出21/40行观测值到mytable.docx文件中，程序如下：

putdocx begin

putdocx pagebreak

putdocx paragraph, halign(left) spacing(after,0) 

putdocx text ("Auto,list in 21/40"), bold

putdocx table tbl = data("make price weight length") in 21/40, varnames width(5.5) 

putdocx save mytable.docx,append

以 上程序跟前边的程序基本相同，只是改变了文本内容和输出数据的范围，另外注意一下width(5.5)选项，其可以设置表格的宽度，单位可以是 in(inch)、pt (point)、cm (centimeter)、twip (twentieth of a point)。默认以in为单位，即英尺。这里我们设置表格宽度为5.5英尺。

执行结果如下所示：

 输出41/60行观测值到mytable.docx文件中，程序如下：

putdocx begin

putdocx pagebreak

putdocx paragraph, halign(center) spacing(after,0) 

putdocx text ("Auto,list in 41/60"), bold

putdocx table tbl = data("make price weight length") in 41/60, varnames layout(autofitcontents) indent(2)  

putdocx save mytable.docx,append

这里把表格设置为以表格内容自动调整列宽，并且用indent(2)选项将表格缩进2英寸，执行结果如下：

输出61/74行观测值到mytable.docx文件中，程序如下：

putdocx begin

putdocx pagebreak

putdocx paragraph, halign(center) spacing(after,0)

putdocx text ("Auto,list in 61/74"), boldputdocx table tbl = data("make price weight length") in 61/74, varnames  width(5.5) 

halign(center) cellspacing(0.08)

putdocx save mytable1.docx,append

这里我们用width选项设置表格宽度为5.5英寸；halign(center)设置表格居中对齐； cellspacing(0.08) 设置相邻单元格之间以及单元格与表格边缘之间的宽度为0.08英寸，执行结果如下：

这样，我们就将list结果加上表头，并以不同的表格格式分批输出到docx文件中，并分页展示。我们也可以通过循环，将list结果分批输出到docx文件中，程序如下：

sysuse auto,clear

forvalue i = 1(20)`=_N'{

    putdocx begin

    putdocx pagebreak

    putdocx paragraph, halign(left) spacing(after,0)

    if `=`i'+19' > `=_N'{

        putdocx text ("Auto,list in `i'/`=_N'"), bold

        putdocx table tbl = data("make price weight length") in `i'/`=_N', varnames width(5.5)

    }

    else {

        putdocx text ("Auto,list in `i'/`=`i'+19'"), bold

        putdocx table tbl = data("make price weight length") in `i'/`=`i'+19', varnames width(5.5)

    }

    putdocx save mytable1.docx,append

}

以上就是今天给大家分享的内容了，说得好就赏个铜板呗！有钱的捧个钱场，有人的捧个人场~。

应广大粉丝要求，爬虫俱乐部的推文公众号打赏功能可以开发票啦，累计打赏超过1000元我们即可给您开具发票，发票类别为“咨询费”。用心做事，只为做您更贴心的小爬虫。第一批发票已经寄到各位小主的手中，大家快来给小爬虫打赏呀~