一般而言，我们将网页爬取的源代码保存为文本文档(.txt)，然后再导入stata进一步的整理分析，往期推文中我们也介绍了将txt文档导入stata的多种导入方式，主要有insheet、infix、import delimited命令以及fileread()函数。因为我们遇到的实际问题往往是多样且复杂的，灵活使用各种方法是很有必要的哟！贴心的爬虫酱为大家总结如下：

首先，我们生成一个文本文件temp.txt，程序如下：

clear all

cd e:\

tempname temp

file open `temp' using temp.txt, text write replace

file write `temp' "爬虫 俱乐部" _n

file write `temp' "将 爬虫进行到底" _n

file write `temp' "number one"

file close `temp'

shellout temp.txt

我们生成的temp.txt有3行内容，且每一行内容都不一样。现在我们用file read命令读入stata，需要说明的是，该命令一次只能读入一行内容，键入如下所示命令：

file open myfile1 using temp.txt,read

file read myfile1 line  

display "`line'"

file close myfile1

结果如下所示：

那如果我们想要读入所有内容，该怎么实现呢？其实，file read命令在读入文本文件的第一行内容后，生成了一个返回值r(eof)，用于判断是否是最后一行的末尾，如果不是，r(eof)=0，否则r(eof)=1。如下所示，刚才读入temp.txt的第一行后，返回值r(eof)=0。

所以，我们可以在读入第一行命令后，对该返回值进行判断，然后继续读入剩下的内容，继续键入命令如下：

file open myfile2 using temp.txt, read

file read myfile2 line 

while r(eof)==0 {

       display "`=word("`line'",1)'"   

       file read myfile2 line

}

file close myfile2

可以看到，将文本的所有行都读进来了。此时，我们看到返回值r(eof)=1

通过前面的介绍，相信大家对file read命令有了简单的认识。不过看得出，前面简单的介绍，并不能体现它的独特之处，接下来，敲黑板、划重点、放大招了哟~

假如，我们想要用file read读入某一路径下同属性的所有文件。下面我们以后缀是txt和dta格式的文件为例展开介绍。首先我们生成一些txt文件和dta文件，命令如下：

cap mkdir e:\fileread

cd e:\fileread

sysuse auto,clear

forvalue i = 1(1)5 {

         drop in 1/5

         outsheet using temp`i'.txt,replace

         save temp`i'.dta,replace

}

我们生成了5个txt文档和5个dta文件

接下来我们想用命令file read把后缀是txt的文件导入stata。在这里，我们用到昨天推文介绍的内容，用到dos命令dir将后缀是txt格式的文件名放在一个文档filelist1.txt中。这里需要注意的是，不能将新生成的文本文件filelist1.txt放在当前的工作路径，是因为该文件名会被视为需要处理的txt文件而列入filelist1.txt中。命令如下：

cap mkdir e:\fileread\sample

! dir *.txt /a-d /b > e:\fileread\sample\filelist1.txt 

shellout e:\fileread\sample\fileli

然后按照刚开始介绍的读入方式，将第一行内容放到局部宏中，接着调用这个局部宏（相当于读入第一个文件的内容），命令如下所示：

file open myfile3 using "e:\fileread\sample\filelist1.txt", read

file read myfile3 line

insheet using `line',names clear  

gen id=_n   

save e:\fileread\sample\mydata1.dta,replace

接下来，通过判断返回值r(eof)的大小，不断读入其他行并进行合并。命令行如下所示：

file read myfile3 line

while r(eof)==0 {

         insheet using `line', clear names

         gen id=_n

         append using e:\fileread\sample\mydata1.dta

         save e:\fileread\sample\mydata1.dta, replace

         file read myfile3 line

}

为了验证数据是否读入，我们做一个简单的描述性统计：

use e:\fileread\sample\mydata1.dta,clear

sum id price mpg

file close myfile3

结果如下：

可以看到6个数据文件已经被合并。

我们也可以用相同的方法合所有dta文件。首先还是用到dos命令dir将所有的dta文件放到一个txt文档：

! dir *.dta /a-d /b >e:\fileread\filelist2.txt

shellout filelist2.txt

接下来，我们读入数据，我们先导入第一个dta 文件，并验证是否被读入：

file open myfile4 using "e:\fileread\filelist2.txt", read

file read myfile4 line

use `line',clear

sum price mpg

file close myfile4

接下来，我们合并其他行，将所有dta文件都导入stata。

clear

file open myfile5 using "e:\fileread\filelist2.txt", read

file read myfile5 line

while r(eof)==0 {

         append using `line'

         file read myfile5 line

}

save mydata2.dta,replace

use mydata2.dta,clear

sum price mpg

file close myfile5

同样看到，6个dta文件已经全部合并完成。

什么？！没看懂！！不要紧！！戳下面，听爬虫小将的详细讲解，也欢迎大家的批评指正哟！

                        文字编辑：高金凤

技术总编：刘贝贝

往期推文推荐：

1.高校学术大神：你的导师上榜了吗？

2.中国高校财经、管理与综合类期刊灌水排行榜